REM 'Handel in the Strand' by Percy A. Grainger
REM (arranged for organ by Wolfgang Stockmeier)
REM Transcribed by Richard Russell, 10-Feb-2026
VDU 23,22,1024;576;8,14,16,8,23,16,1;0;0;0;28,29,13,97,2 : OFF
OSCLI "DISPLAY """ + @dir$ + "organ.jpg"""
OSCLI "GSAVE """ + @tmp$ + "swell.bmp"" 1016,220,90,160"
OSCLI "FONT """ + @lib$ + "DejaVuSansMono"",7"
ON MOVE PROCresize(@msg%, @lparam%, @size.x%, @size.y%) : RETURN
COLOUR 0,48,16,0
COLOUR 1,240,240,224 : COLOUR 129 : COLOUR 8
COLOUR 2,&F0,&E0,&C0
COLOUR 3,&A0,&96,&80
COLOUR 6,255,255,127
GCOL 1 : RECTANGLE FILL 450,758,1122,336 : RECTANGLE 1250,460,192,250 TO 1246,460
FOR I% = 0 TO 60 : PROCdrawkey(I%, TRUE, 1) : PROCdrawkey(I%, TRUE, TRUE) : NEXT
FOR I% = 0 TO 60 : PROCdrawkey(I%,FALSE, 1) : PROCdrawkey(I%,FALSE, TRUE) : NEXT
FOR I% = 0 TO 29 : PROCdrawkey(I%,FALSE, 0) : NEXT
*TEMPO 133
*STEREO 0,-84
*STEREO 1,-42
*STEREO 2,42
*STEREO 3,84
*VOICE 0,5
*VOICE 1,5
*VOICE 2,5
*VOICE 3,5
SOUND 1,0,0,20
ENVELOPE 1,1,0,0,0,0,0,0,64,0,0,-4,18,0
ENVELOPE 2,1,0,0,0,0,0,0,64,0,0,-4,36,6
ENVELOPE 3,1,0,0,0,0,0,0,64,0,0,-4,54,24
ENVELOPE 4,1,0,0,0,0,0,0,64,0,0,-4,72,42
ENVELOPE 5,1,0,0,0,0,0,0,64,0,0,-4,90,60
ENVELOPE 6,1,0,0,0,0,0,0,64,0,0,-4,108,78
ENVELOPE 7,1,0,0,0,0,0,0,64,0,0,-4,127,96
DIM Q1&(3), Q2&(3), Q3&(3), Q4&(3), W&(3)
DIM snd{(3,50)a&,e&,p&,d&}, p%(3), q%(3), cli$(3), envel%(3)
DIM cmajor&(7), scale%(7), acc%(7), flat&(7), sharp&(7)
cmajor&() = 88,96,52,60,68,72,80
flat&() = 0, &02, &12, &13, &1B, &5B, &5F, &7F
sharp&() = 0, &A0, &A4, &E4, &EC, &ED, &FD, &FF
dur% = 24
tempo = 2
REPEAT
REPEAT
READ R$ : IF R$="" REPEAT WAIT 4 : PROCpoll : UNTIL FALSE
T$ += R$ : IF RIGHT$(T$) = "\" T$ = LEFT$(T$)
UNTIL RIGHT$(R$) <> "\"
PRINT ' R$;
acc%() = scale%()
clef% = 48 : voice% = 1
p%() = 0 : q%() = 0
WHILE T$<>""
I% = 1 : WHILE INSTR("0123456789",MID$(T$,I%,1)) I% += 1 : ENDWHILE
IF I% > 1 dur% = VALLEFT$(T$,I%-1) : T$ = MID$(T$,I%)
C$ = LEFT$(T$,1) : T$=MID$(T$,2)
CASE C$ OF
WHEN " ":
WHEN ";": T$ = ""
WHEN "[": T$ = ""
WHEN "P": T$ = MID$(T$,2)
WHEN "=": beat% = 0
WHILE ASC(T$)>=&30 AND ASC(T$)<=&39 beat% = beat% * 10 + ASC(T$)-&30
T$ = MID$(T$,2) : ENDWHILE
WHILE ADVAL(-5)<16 OR ADVAL(-6)<16 OR ADVAL(-7)<16 OR ADVAL(-8)<16
WAIT 1 : ENDWHILE
CASE TRUE OF
WHEN beat% <= 60 tempo = 3 : *TEMPO 130
WHEN beat% <= 70 tempo = 4 : *TEMPO 131
WHEN beat% <= 100 tempo = 3 : *TEMPO 131
WHEN beat% <= 120 tempo = 4 : *TEMPO 133
WHEN beat% <= 130 tempo = 3 : *TEMPO 132
WHEN beat% <= 150 tempo = 2 : *TEMPO 131
WHEN beat% <= 170 tempo = 3 : *TEMPO 133
WHEN beat% <= 200 tempo = 2 : *TEMPO 132
WHEN beat% <= 250 tempo = 2 : *TEMPO 133
WHEN beat% <= 300 tempo = 2 : *TEMPO 134
ENDCASE
WHEN "T": acc%() = scale%() : clef% = 48
WHEN "S": acc%() = scale%() : clef% = 0
WHEN "V": acc%() = scale%() : voice% = ASC(T$) - &30 : T$=MID$(T$,2)
voice% AND= 3
WHEN "W": wave% = VAL(T$) : T$ = MID$(T$,2)
WHILE ADVAL(-5-voice%)<16 WAIT 1 : ENDWHILE
cli$(voice%) = "voice " + STR$voice% + "," + STR$(wave%)
PROCstop(voice%, wave%)
WHEN "N": envel%(voice%) = VAL(T$) : T$ = MID$(T$,2)
IF voice% = 1 OR voice% = 2 PROCswell(envel%(voice%))
WHEN "K": key% = ASC(T$) - &30 : T$=MID$(T$,2)
scale%() = 0
IF key% THEN
key$ = LEFT$(T$,1) : T$=MID$(T$,2)
CASE key$ OF
WHEN "#": key& = sharp&(key%)
WHEN "b","&": key& = flat&(key%)
ENDCASE
FOR I% = 0 TO 6
IF key& AND (2^I%) scale%(I%) = -4 : IF key& AND &80 scale%(I%) = +4
NEXT
ENDIF
acc%() = scale%()
OTHERWISE
Note% = INSTR("ABCDEFG$",C$)-1
IF Note% < 0 ERROR 100, "Unrecognised command "+C$
octave% = 0
staccato = 0
ticks% = dur% / tempo
REPEAT
CASE LEFT$(T$,1) OF
WHEN "#": acc%(Note%) = 4
IF MID$(T$,2,1) = "#" acc%(Note%) = 8 : T$=MID$(T$,2)
WHEN "%": acc%(Note%) = 0
WHEN "&","b": acc%(Note%) =-4
WHEN "+": octave% += 48
WHEN "-": octave% -= 48
WHEN ".": ticks% = dur% / tempo * 3/2
WHEN ":": ticks% = dur% / tempo * 2/3
WHEN ",": staccato = 1/3
WHEN "'": staccato = 1/4
WHEN """": staccato = 1/6
OTHERWISE: EXIT REPEAT
ENDCASE
T$=MID$(T$,2)
UNTIL FALSE
pitch% = cmajor&(Note%) + acc%(Note%) + clef% + octave%
IF Note% = 7 pitch% = 0
IF pitch% < 0 OR pitch% > 255 ERROR 100, "Pitch out of range: "+STR$pitch%
IF ticks% < 0 OR ticks% > 254 ERROR 100, "Duration out of range: "+STR$ticks%
gap% = INT(ticks% * staccato) + 0.5
snd{(voice%,p%(voice%))}.e& = envel%(voice%)
snd{(voice%,p%(voice%))}.p& = pitch%
snd{(voice%,p%(voice%))}.d& = ticks% - gap%
p%(voice%) += 1
IF gap% THEN
snd{(voice%,p%(voice%))}.p& = 0
snd{(voice%,p%(voice%))}.d& = gap%
p%(voice%) += 1
ENDIF
ENDCASE
ENDWHILE
WHILE ADVAL(-5)=0 OR ADVAL(-6)=0 OR ADVAL(-7)=0 OR ADVAL(-8)=0
PROCpoll : WAIT 1
ENDWHILE
IF p%(0)<>q%(0) OR p%(1)<>q%(1) OR p%(2)<>q%(2) OR p%(3)<>q%(3) THEN
SOUND &300,0,0,0 : SOUND &301,0,0,0 : SOUND &302,0,0,0 : SOUND &303,0,0,0
PROCevent(0,0) : PROCevent(1,0) : PROCevent(2,0) : PROCevent(3,0)
FOR v% = 0 TO 3
IF cli$(v%)<>"" OSCLI(cli$(v%)) : cli$(v%) = ""
NEXT
REPEAT
stall% = TRUE
FOR v% = 0 TO 3
IF q%(v%) < p%(v%) IF ADVAL(-5-v%) THEN
stall% = FALSE
IF snd{(v%,q%(v%))}.p& = 0 THEN
SOUND v%+&1000,snd{(v%,q%(v%))}.e&,0,snd{(v%,q%(v%))}.d&
ELSE
SOUND v%,snd{(v%,q%(v%))}.e&,snd{(v%,q%(v%))}.p&,snd{(v%,q%(v%))}.d&
ENDIF
PROCevent(v%, snd{(v%,q%(v%))}.p&)
q%(v%) += 1
ENDIF
NEXT v%
IF stall% PROCpoll : WAIT 1
UNTIL p%(0)=q%(0) AND p%(1)=q%(1) AND p%(2)=q%(2) AND p%(3)=q%(3)
ENDIF
UNTIL FALSE
END
DEF PROCstop(V%, W%) W&(V%) = W%
PRIVATE done%() : DIM done%(3)
GCOL 2,6
CASE TRUE OF
WHEN V%=0: IF done%(1) ENDPROC ELSE done%(1) = TRUE
RECTANGLE FILL 1898,526,130,124 TO 1868,530 : REM Pedal -> Open Diapason
RECTANGLE FILL 1868,530,130,124
WHEN V%=1: IF done%(2) ENDPROC ELSE done%(2) = TRUE
RECTANGLE FILL 1754,530,130,124 TO 1724,534 : REM Great -> Open Diapason
RECTANGLE FILL 1724,534,130,124
WHEN W%=6: IF done%(3) ENDPROC ELSE done%(3) = TRUE
RECTANGLE FILL 168,656,130,124 TO 196,660 : REM Swell -> Viola da Gamba
RECTANGLE FILL 196,660,130,124
ENDCASE
ENDPROC
REM Poll the current sound queue status; if the queue is not empty
REM a sound is currently playing, in which case we can update the
REM visible keyboard state:
DEF PROCpoll
LOCAL A%, I%, P%
PRIVATE p&(), w&() : DIM p&(3), w&(3)
FOR I% = 0 TO 3
A% = ADVAL(-5-I%) DIV 4 : REM Free slots
IF A% = 4 THEN
IF p&(I%) PROCdrawkey(p&(I%) - 1, FALSE, I% OR w&(I%)=6)
p&(I%) = 0 : w&(I%) = 0
ELSE
CASE I% OF
WHEN 0: P% = Q1&(3-A%) DIV 4
WHEN 1: P% = Q2&(3-A%) DIV 4
WHEN 2: P% = Q3&(3-A%) DIV 4
WHEN 3: P% = Q4&(3-A%) DIV 4
ENDCASE
IF P% <> p&(I%) THEN
IF p&(I%) PROCdrawkey(p&(I%) - 1, FALSE, I% OR w&(I%)=6)
IF P% PROCdrawkey(P% - 1, TRUE, I% OR W&(I%)=6)
ENDIF
p&(I%) = P% : w&(I%) = W&(I%)
ENDIF
NEXT
ENDPROC
DEF PROCdrawkey(P%, F%, V%)
LOCAL D%, H%, T%, W%, X%, Y%, t
D% = 24 : H% = 32 : W% = 22 : X% = 578
IF V% = TRUE Y% = 616 ELSE Y% = 460
IF V% = FALSE W% = 16 : X% = 588 : Y% = 40 : D% = 49 H% = 64
t = (P% MOD 12 + 0.4) * 0.56 : T% = INT(t)
X% += (P% DIV 12 * 7 + T%) * D%
IF (t - T%) < 0.5 THEN
IF F% GCOL 3 ELSE GCOL 2 : W% -= 2
RECTANGLE FILL X%+2,Y%,W%,H%
ELSE
IF F% GCOL 3 ELSE GCOL 8
RECTANGLE FILL X%+D%/2+4,Y%+H%+4,14,H%/2+36
ENDIF
ENDPROC
DEF PROCswell(N%)
PRIVATE S% : IF N% = S% ENDPROC
S% = N% : N% = 160 * COS(N% / 6)
GCOL 0 : RECTANGLE FILL 1016,220,90,160
OSCLI "DISPLAY """ + @tmp$ + "swell"" 1016," + STR$(300-N% DIV 2) + ",90," + STR$N%
ENDPROC
REM Keep a copy of all SOUND events in our own private queues:
DEF PROCevent(K%, P%)
CASE K% OF
WHEN 0:
Q1&() = P%,Q1&(0),Q1&(1),Q1&(2)
WHEN 1:
Q2&() = P%,Q2&(0),Q2&(1),Q2&(2)
WHEN 2:
Q3&() = P%,Q3&(0),Q3&(1),Q3&(2)
WHEN 3:
Q4&() = P%,Q4&(0),Q4&(1),Q4&(2)
ENDCASE
ENDPROC
DEF PROCresize(M%, L%, X%, Y%) IF M% <> 5 ENDPROC
LOCAL W%, H%
W% = L% AND &FFFF
H% = L% >>> 16
IF W%/H% > X%/Y% THEN
@zoom% = &8000 * H% / Y%
ELSE
@zoom% = &8000 * W% / X%
ENDIF
IF @zoom% < &8000 @zoom% = &8000
IF (@platform% AND 7) < 3 OR (@platform% AND 7) > 4 THEN
@panx% = (X% - W% * &8000 / @zoom%) / 2
@pany% = (Y% - H% * &8000 / @zoom%) / 2
ENDIF
ENDPROC
DATA "[ 'Handel in the Strand' by Percy A. Grainger"
DATA "[ (arranged for organ by Wolfgang Stockmeier)"
DATA "[ Transcribed by Richard Russell, 07-Feb-2026"
DATA K1#
DATA =250
DATA V1W5V2W5V3W5V4W5
DATA V1N4V2N4V3N4V4N6
DATA [ Page 1
DATA TV1 12 B'D+'C+'A' B'D+'C+'A' V2 D'D'E'D' D'D'E'C' SV3 G'G'A'A' G'G'A'A' V4 G-B-A-D G-B-A-D [Bar 1
DATA TV1 12 B'D+'A'D+' G'C#+'D+'C%+' V2 D'D'C#'D' D'E'F'D' SV3 G'B'A'A' B'A'A'A' V4 G-'G'F-'F' E'A-'D'F'
DATA TV1 12 B'D+'C+'A' B'D+'C+'A' V2 D'D'E'D' D'D'E'C' SV3 B'G'A'A' G'G'A'A' V4 G-'B-'A-'D' G-'B-'A-'D'
DATA TV1 12 B'D+'A'D+' G'C#+'D+'C%+' V2 D'D'C#'D' D'E'F'D' SV3 G'B'A'A' B'A'A'$ V4 G-'G'F-'F' E'A-'D'F' [Bar 4
DATA V3W6 V3N6
DATA TV1 12 B'D+'E+'C+' D+'G+F+E+ V2 D'D'E'F' G'BGF V3 96G SV4 12 G-B-CA- B-G-CA-
DATA TV1 12 D+B'C+'D+' B'C+'D+'C+' V2 GD'E'F' D'E'F'E' V3 GGFE DB-24A- SV4 12 B-G-A-D G-B-DD
DATA TV1 12 B'D+'C+'E+' D+'G+F+E+ V2 DDEF GBGG V3 24 B-CDE SV4 12 G-GA-A B-BCA- [Bar 7
DATA TV1 12 D+C+BA' B'A'24G V2 12 FFEE' D'C'24B- V3 24 F12GC24DG- SV4 12 DDEA- DD24G-
DATA TV1 12 B'D+'C+'A' B'D+'C+'A' V2 D'D'E'D' D'D'E'C' V3 96 D SV4 12 G-B-'A-'D' G-'B-'A-'D'
DATA [ Page 2
DATA TV1 12 B'D+'A'D+' G'C#+'D+'C%+' V2 D'D'C#'D' D'E'F'D' V3 60 D12C#24D SV4 12 G-'G'F'-F'E'A-'D'F'[Bar 10
DATA TV1 12 BD+C+A BD+C+A V2 DDED DDEC% V3 96 D SV4 12 G-B-A-D G-B-A-D
DATA TV1 12 BD+AD+ GC#+D+C%+ V2 DDC#D DEFD V3 60 D12C#24D SV4 12 G-GF-F EA-DF
DATA TV1 12 BD+E+C+ D+G+F+E+ V2 DDEF GBGF V3 96 G SV4 12 G-B-CA- B-G-CA- [Bar 13
DATA TV1 12 D+B'C+'D+' B'C+'D+'C+' V2 GD'E'F' D'E'F'E' V3 GGFE DB-24A- SV4 12 B-G-A-D G-B-DD
DATA TV1 12 B'D+'C+'E+' D+'G+F+E+ V2 D'D'E'F' G'BGG V3 24 B-CDE SV4 12 G-GA-A B-BCA-
DATA TV1 12 D+C+BA B'A'24G V2 12 FFEE D'C'24D V3 24 F12GC24DG- SV4 12 DDEA- DD24G- [Bar 16
DATA V1N5 V3W5 V3N5
DATA TV1 24 B.12A 24GD V2 12 B-'D'C'C' B-'D'C'A-' SV3 D'G'G'F' G'G'E'F' V4 G-'B-'A-'D' G-'B-'A-'D'
DATA TV1 12 DD+E+F+ 6G+F+12E+24D+ V2 12 B-SD+C+C+ D+T6AG12FE SV3 GGGA GC#+AC%+ V4 G-B-CD G-A-D-D
DATA TV1 12 D+G+E+.6F+ 12D+G+C+.6D+ V2 12 DGD+C+ C+BBA SV3 BD+BC+ D+D+C+C+ V4 G-B-CA- B-G-D-E [Bar 19
DATA TV1 12 BD+G+F+ F+E+6F+E+12D+ V2 12 AGBA A.6GAGGF SV3 12 D+D+6D+C#+12D+24B12C+D+ V4 D-GEF GEA-D
DATA TV1 24 F%+E+G+F#+ V2 BC+C#+12D+C%+ SV3 D+'D+'C+'E+' E+'E+'D+'F+' V4 G-GCB- A-ADD#
DATA [ Page 3
DATA TV1 12 G+B+A+F+ 24E+D+ V2 12 BC#+24D+ 12D+C+24A SV3 12 E+'E+'D+'E+' 48A V4 12 EEFB- A-ADD [Bar 22
DATA TV1 12 D+G36E+12A24F+ V2 12 C+B24C+12D+C#+6D+C+BA SV3 24D+12C+D+24E+12D+C+ V4 12 G-GCBb- A-ADD#
DATA TV1 12 G+.6B12C+D+C+B24A V2 48G 12G#G%GF# SV3 BBAB D+E+E+D+ V4 ED%GC EA-24D
DATA V1N6 V2N6 V3N6
DATA SV1 12 B TD+C+.6B 24D+.12C+ SV2 G TBA.6G 24B.12A SV3 D$D$$D'E'F' V4 G-$B-$48D- [Bar 25
DATA TV1 24 BD+B.12A V2 24 A12G.6F24E.12D SV3 12 $D+C+.6B 12D+DEF V4 G-$B-$48D-
DATA TV1 24 GD12EG24A V2 12 $DC.6B- 12DCFE SV3 D$D$G$DC V4 G-$B-$C-'C'D-'D'
DATA TV1 12 BD+24E+ 48F+ V2 12 DBC#+BD+C%+B.6A SV3 12 GBC#+D+E+D+.6C%+ V4 12 G-G24A 48D- [Bar 28
DATA TV1 12 $G+F+.6G+ 24E+12F+D+ V2 G24G12G BABA SV3 B24B12B24 E+12D+C+ V4 G-GB-DCC+DF
DATA TV1 12 B24E+12D+GC+24B V2 12 GBF%BGC+24G# SV3 12 BGF%GGC+BD V4 E6$G- 12A-B- 24CE
DATA TV1 12 EF6G12B6$ 12AB6C+#12E+ V2 24 C#DGA SV3 12 EF6G12B6$24D+C#+ V4 A-B- 48E- [Bar 31
DATA TV1 24 G+12D+B24AG V2 D+12BG24FG SV3 12 D6GA12BC+D+C+B V4 48 D- 24 DG-
DATA V1N7 V2N7 V3N7
DATA TV1 12 $D+C+.6B 24 D+.12C+ V2 $BA.6G 24B.12A SV3 24 GG 12$DEF V4 24 G-B-48D-
DATA [ Page 4
DATA TV1 24 BD+B.12A V2 24A12G.6A 24E.12D SV3 $D+C+.6B12D+DEF V4 24G-B-48D- [Bar 34
DATA TV1 12 GD+C+.6B 12D+C+BA V2 DBA.6G 12BEDC SV3 24 BG 12EG 24B V4 24 G-B-C-D-
DATA TV1 12 GBA.6G 12F 6D:E:F:G:A:B:C+:D+:E+: V2 12 B-D 24E 12D SV3 24 EED. V4 E-A- 48 D-
DATA TV1 12 G+G+F+.6G+24E+12F+D+ V2 B24B.12D+C+BA V3 D24D.12DC SV4 24G-.12B-24CD [Bar 37
DATA TV1 12 B24E+12D+GC+24B V2 12 GGF%G24E.12D V3 B- SGF%GGC+24B SV4 EG- 6C-D-D#-E-F%-F#-
DATA TV1 12 EF6G12B.AB6C#+12E+ V2 24 C#DGA SV3 12 EF6G12B.24D+C+# V4 24 A-B-48E- [Bar 39
DATA TV1 24 G+12D+B24AG V2 B12GG24DD SV3 12G6GA12DEFE24D V4 48 D-24 DG-
DATA V1N6 V2N6 V3N6
DATA TV1 24 $F%+G+A+ V2 $BbD+Eb+ SV3 D+D+D+C+ V4 G-DEbF%
DATA TV1 6 Bb+A+12B+6A+G+12A+D+ V2 6 BbA12B6AG12AA SV3 BbC+D+Eb+F%+ V4 G-A-Bb-CD [Bar 42
DATA TV1 24 G+F%+Bb V2 GAbF% SV3 BbC+B V4 Eb 48 Bb-
DATA TV1 12 Eb+6D+C+12D+GC+6GA V2 12 GAbA%F%EbC# SV3 BbBC+BGB V4 Eb-F%-F#-G-CEb
DATA [ Page 5
DATA TV1 6 BbA12BG.6A V2 12 DDC#D SV3 GGGG V4 DDEbD [Bar 45
DATA TV1 6 BbA12BG V2 EbE%D# SV3 GGG V4 DbCB%-
DATA TV1 24 C+C#+ V2 E%F% SV3 GG V4 Bb-A-
DATA TV1 12 D+A+B+6A+G+12A+F+6G+:A+:G+:F+E+ V2 12 F#D+E+C%+D+D+24C+ SV3 12ATFGESATFGE SV4 96D [Bar 48
DATA TV1 12 F+D+E+6BC+12D+BAD V2 D+AG6AG12FEDD SV3 AAAAFEFD V4 DD'A-'A'DA-DD
DATA V1N7 V2N7 V3N7
DATA TV1 12 G-G+F+.6G+24E+12F+D+ V2 $24D+.12D+C+D+C+ SV3 G-TGF.6G12DCDC SV4 24 G-.12B-24CD
DATA TV1 12 B24E+12D+GC+24B V2 12 GGF%G6EF12E6ED#12D% V3 B-S6$GG#AA#BC+C#DD#24E V4 24EG-GE- [Bar 51
DATA TV1 12 EF6G12B.AB6C#+12E+. V2 24 C#DGA SV3 C#D48E V4 24 A-B-48E-
DATA TV1 24 G+12D+B 24G+12D+B V2 24B12GG 24B12GG SV3 B6GA12BC%+B6GA12BC+ V4 48 D-'D-
DATA TV1 24 G+12D+B48A 12G V2 24B12G'G 24EF 12D SV3 12B6GA12BC+48G 12G V4 96 D- 12G- [Bar 54
DATA V1W5 V2W5 V3W6 V1N4 V2N4 V3N6
DATA TV1 12 D+'C+'A'B'D+'C+'A' V2 G'G'F'G'G'F'C' V3 84 D SV4 12 B-'A-'D'G-'B-'A-'D'
DATA TV1 12 B'D+'A'D+'G'C#+'D+'C%+' V2 G'G'A'A'G'G'A'A' V3 48D12DC#24D V4 12 G-'G'F-'F'E'A-'D'F'
DATA [ Page 6
DATA TV1 12 B'D+'C+'A'B'D+'C+'A' V2 G'G'G'F'G'G'G'C' V3 96 D SV4 12 G-'B-'A-'D'G-'B-'A-'D' [Bar 57
DATA TV1 12 B'D+'A'D+'G'C#+'D+'C%+' V2 G'G'A'A'G'G'A'A' V3 48 D12DC#24D SV4 12 G-'G'F-'F'E'A-'D'F'
DATA TV1 12 B'D+'E+'C+'D+'G+F+E+ V2 D'D'E'F'G'BGF V3 96 G SV4 12 G-'B-'C'A-'B-'G-CA-
DATA TV1 12 D+'B'C+'D+'B'C+'D+'C+' V2 G'G'G'F'G'G'F'F' V3 GGFEDB-24A- SV4 12 B-G-A-DG-B-DD [Bar 60
DATA TV1 12 B'D+'C+'E+'D+'G+F+E+ V2 D'D'E'F'G'BGG V3 24 B-CDE SV4 12 G-GA-AB-BCA-
DATA TV1 12 D+C+BA'B'A'24G 12 V2 BAGG'F'C'24B- V3 24 F12GC24DG- SV4 12 DDEA-DD24G-
DATA V1N5 V3W5 V3N5 V3W5
DATA TV1 24 B.12A24GD V2 12 B-'D'E'D'B-'D'C'A-' SV3 D'G'G'F'G'G'E'F' V4 G-'B-'A-'D'G-'B-'A-'D'[Bar 63
DATA TV1 12 DD+E+F+6G+F+12E+24D+ V2 12 B-DCCB6AG12FE SV3 GGGGD+C#+D+A+ V4 G-B-CA-G-A-DC
DATA TV1 12 D+G+E+.6F+12D+G+C+.6D+ V2 12 DGD+C+C+BBA SV3 GB T GFFEED SV4 B-G-CA-B-G-A-F-
DATA TV1 12 BD+G+F+F+E+6F+E+12D+ V2 AGBAAG24B 12 V3 DDC#DDDC#D SV4 G-F%-E-F#-G-E-A-D- [Bar 66
DATA V1N6V2N6V3N6
DATA TV1 24 F%+E+G+F#+ 12 V2 C%+BD+C+BbAE+D#+ SV3 D+GE+E+A24F+ V4 G-12CBb-DC#C%B%-
DATA TV1 24 G+B+ 12A+F+ 24 E+ V2 BC#+12D+B D+C+ V3 24EG 12FEDC# SV4 24 E-E12FGAA-
DATA [ Page 7
DATA TV1 12 D+A+B+6A+G+12A+F+6G+:A+:G+:F+E+ V2 12 FD+E+C+D+D+24C+ V3 12 A-FGEA-FGE SV4 96 D [Bar 69
DATA TV1 12 F+D+E+6BC+12D+6B:C+:B:12AGF6E:F:G:A:B:C+:D+:E+: V2 12 D+AG6AG12AGFED SV3 AABAAC+D+BAB24A V4 132D12C
DATA TV1 24 F%+E+G+F#+ V2 GGAA V3 D12CD24E12DC% SV4 24 B-12CBb-24A-12DD# [Bar 71
DATA TV1 12 G+B+A+F+48E+ V2 12GC#+D+B24BA V3 12 B-GF#FS24BC#+ V4 12 EE-F-G-48A-
DATA TV1 12 D+A+B+6A+G+12A+F+6G+:A+:G+:F+E+ V2 12FD+E+C+D+D+24C+ SV3 12ATFGEA-FGE V4 96D
DATA TV1 12 F+D+E+6BC+ V2 12 D+AG6AG SV3 12 AABA V4 48 D [Bar 74
DATA TV1 12 D+6B+:C+:B+:12A+G+F+E+D+6B+:C+:B+: V2 12 AE+D+BC+BFE+ V3 A-GFDCB-A-C SV4 DA-DA-DA-D-A-
DATA TV1 13 A+G+15F+G+17BC+20D+D+ V2 13 D+B15AG17EE20GG V3 13 FE15DB-17SGG20GG V4 13DA-15DE17A-A-20DD-
DATA V1N7V2N7V3N7V4N7
DATA TV1 12 DD+C+.6B24D+.12C+ V2 12 D-BA.6G24G.12D SV3 48B 12$6DE12F%F# V4 24 G-B-48D- [Bar 77
DATA TV1 24 BD+B.12A V2 24 A 12G.6F24E.12D SV3 12$D+C+.6B12D+6DE12F%F# V4 24 G-B-48D-
DATA [ Page 8
DATA TV1 12 GD+C+.6B12D+C+BA V2 DBA.6G12BADC SV3 24BG12EG24A V4 G-B-C-D- [Bar 79
DATA TV1 12 GBAGF6D:E:F:G:A:B:C+:D+:E+: V2 12 B-DC#B-D CB-.6A- SV3 48E12FED.6E V4 24 E-A-48D-
DATA TV1 12 G+G+F+.6G+24E+12F+D+ V2 B24B.12D+C+BA SV3 12DT24D.E12DC SV4 24G-.12B-24CD [Bar 81
DATA TV1 12 B24E+12D+GC+24B V2 12 GGF%G24E.12D V3 B-SGF%GGC+24B V4 24 EG-6C-D-D#-E-F%-F#-G%-G#-
DATA TV1 12 EF6G12B. V2 24 C#D SV3 12 EF6G12B. V4 24 A-B-
DATA TV1 12 AB6C#+12E+.24E+ V2 24 GAE SV3 48A 4 C#DEGAB V4 48 E- 24 A- [Bar 84
DATA TV1 24 G+12D+B28G+14D+B V2 24 D+12BG28D+14BG SV3 12B6GA12BC+14B7GA14BC+ V4 104 D-
DATA TV1 32 G+16D+B 64 A V2 32 D+16BG 32GF SV3 16B8GA16BC+ 64 C V4 128 D-
DATA TV1 20G 12 G+'F+'E+'D+'C+'B'A' V2 20D 6C+'A'B'G'A'F'G'E'F'D'E'C'D#'B-' V3 20B-12GFEDCB-A- SV4 20 G- [Bar 87
DATA TV1 8 GABC+ 16D+E+ 100G+ V2 8 EFGA 16BC+ 100D+ SV3 16 GABC+ 100B V4 16 EEbDD 100G-
DATA ""